home *** CD-ROM | disk | FTP | other *** search
/ CD ROM Paradise Collection 4 / CD ROM Paradise Collection 4 1995 Nov.iso / asm / alib11b.zip / CODE1.ZIP / DEBUG / KEYBREAK.ASM next >
Assembly Source File  |  1994-10-03  |  5KB  |  106 lines
  1. ; 
  2. ; This code creates a debug abort key which will transfer control
  3. ; back to most debug programs.  Hitting the '5' key forces an
  4. ; int 3 (debug breakpoint).
  5. ;
  6. ; By Garrett P. Nievin
  7. ;
  8. ; To add a hardware breakout switch just put a switch between
  9. ; pins 17 (NMI) and 40 (+5V) on your 8088 chip, and a switch between
  10. ; pins 21 (RESET) and 40 will do a system reset/reboot.)
  11. ;
  12. ; This is a .COM program
  13.  
  14. code    segment para public 'code'
  15.         assume cs:code,ds:nothing,es:nothing
  16.         org     0100h
  17.  
  18. hotkey  equ     4ch         ; scan code for hot key = "5" on keypad
  19. portA   equ     60h         ; 8255A port A, usually keybd scan code
  20. portB   equ     61h         ; 8255A port B, various switches
  21. release equ     80h         ; hi bit in scan code means key release
  22. hibiton equ     80h         ; hi bit in byte for or'ing in
  23. hbitoff equ     7fh         ; hi bit in byte for and'ing out
  24.  
  25. start   proc    far
  26. begcode:
  27.     jmp  implant            ; jump around interrupt handler code
  28. begres:                     ; area to remain core resident
  29.  
  30. rescode  proc               ; keystroke causes jump to here
  31.     jmp  over               ; jump over memory signature
  32.     db  'bcGN'              ; program signature in memory
  33. over:                       ;
  34.     sti                     ; allow interrupts
  35.     push ax                 ; save that register
  36.     in   al,portA           ; get keyboard scan code
  37.     cmp  al,hotkey          ; hotkey?
  38.     jne  normal             ; yes, go hanlit
  39.     push dx                 ; save register
  40.     mov  dx,0020h           ; port 20h = PIC port to send EOI to
  41.     mov  al,dl              ; 20h turns on EOI bit
  42.     out  dx,al              ; tell interrupt controller we be done
  43.     pop  dx                 ; restore register
  44.     in   al,portB           ; get portB
  45.     or   al,hibiton         ; set acknowledge / clear keyboard bit
  46.     out  portB,al           ; and out it again
  47.     and  al,hbitoff         ; clear ack bit
  48.     out  portB,al           ; out that, enabling keyboard again
  49.     pop  ax                 ; restore original register
  50.     int  3                  ;
  51.     iret                    ;
  52.  
  53. normal:                     ;
  54.     pop  ax                 ; restore that register
  55.     jmp  dword ptr cs:oldint9    ; goto old int9 handler
  56. oldint9  dw  0,0            ; doubleword value of old int9 vector
  57. rescode  endp
  58.  
  59. endres:                     ; end of core res area
  60.  
  61. reslen  equ endres - begres           ; length of new resident code
  62. strtres equ begres - begcode + 100h   ; start of resident code
  63. psplen  equ 5ch                       ; length of necessary PSP
  64.  
  65. implant:                    ; code to put new int 9 front end in core
  66.     mov  ax,3509h           ; get int vector function
  67.     int  21h                ; get vector of interrupt 9 handler
  68.     cmp  es:[bx+3],'cb'     ; already loaded?
  69.     jne  fresh              ; nope, go install
  70.     cmp  es:[bx+5],'NG'     ; make sure
  71.     jne  fresh              ; naaah, go install
  72.     lea  dx,cs:stalemsg     ; DX points to already installed message
  73.     mov  ah,09h             ; DOS display string func
  74.     int  21h                ; go display message
  75.     mov  ax,4cffh           ; terminate with code = 0xff
  76.     int  21h                ;
  77.         
  78. fresh:
  79.     lea  dx,cs:instlmsg     ; DX points to installation message
  80.     mov  ah,09h             ; display string function
  81.     int  21h                ; give the user the poop
  82.     mov  ax,3509h           ; get int vector function
  83.     int  21h                ; get vector of old interrupt 9 handler
  84.     mov  oldint9,bx         ; int location in ES:BX, save it
  85.     mov  oldint9+2,es       ; "
  86.     mov  ax,2509h           ; set new interrupt 9 vector to me
  87.     mov  dx,offset rescode  ; address of which is in DX
  88.     int  21h                ; go do it
  89.     push cs                 ; DS and ES both end
  90.     pop  es                 ; up pointing at
  91.     push cs                 ; code area
  92.     pop  ds                 ; "
  93.     mov  di,psplen          ; where program will end up
  94.     mov  si,strtres         ; start of resident code
  95.     mov  cx,reslen          ; amount of resident code to move
  96.     cld                     ; go forward in move
  97.     rep  movsb              ; move code back in mem
  98.     mov  dx,psplen + reslen ; DX pointing to next free paragraph
  99.     mov  ax,3100h           ; keep, return code of 0
  100.     int  21h                ; terminate
  101. stalemsg db 'Bugout already resident.',10,13,7,'$'
  102. instlmsg db 'Bugout loaded and active, keypad-5 is break key.',10,13,'$'
  103. start    endp
  104. code     ends
  105.     end  start
  106.